# Battle for Wesnoth
# TODO:
# - have the locales packages really depend on the needed font if any
# - split locales packages into per-domain packages
# - do not ship empty .mo files
# - make data packages arch:all
## - give correct short description to all packages

DESCRIPTION = "Battle for Wesnoth turned-based strategy game"
SECTION = "opie/games"
PRIORITY = "optional"
LICENSE = "GPL"
MAINTAINER = "Yann Dirson <ydirson@altern.org>"

SRC_URI = "${SOURCEFORGE_MIRROR}/${PN}/${PN}-${PV}.tar.gz"

pkgddir = "${datadir}/wesnoth"

DEPENDS = "virtual/libsdl libsdl-image libsdl-net libsdl-mixer freetype zipios++"

inherit autotools 

EXTRA_OECONF = "--with-localedir=/usr/share/locale \
		--enable-editor \
		--enable-tinygui \
		"

do_install() {
	oe_runmake 'DESTDIR=${D}' zip-install
}

PACKAGES = "wesnoth wesnoth-data wesnoth-editor wesnoth-sound wesnoth-music \
	wesnoth-campaign-httt wesnoth-campaign-ei \
	wesnoth-campaign-sotbe wesnoth-campaign-tdh wesnoth-campaign-trow \
	wesnoth-font-freesans wesnoth-font-bepa \
	wesnoth-dev "

DESCRIPTION_wesnoth-data = "Battle for Wesnoth - essential data"
DESCRIPTION_wesnoth-sound = "Battle for Wesnoth - sound effects"
DESCRIPTION_wesnoth-music = "Battle for Wesnoth - background music"
DESCRIPTION_wesnoth-campaign-httt = "Battle for Wesnoth main campaign - Heir to the Throne"
DESCRIPTION_wesnoth-campaign-ei = "Battle for Wesnoth campaign - Eastern Invasion"
DESCRIPTION_wesnoth-campaign-sotbe = "Battle for Wesnoth campaign - Son of the Black Eye"
DESCRIPTION_wesnoth-campaign-tdh = "Battle for Wesnoth campaign - The Dark Hordes"
DESCRIPTION_wesnoth-campaign-trow = "Battle for Wesnoth campaign - The Rise of Wesnoth"
DESCRIPTION_wesnoth-editor = "Battle for Wesnoth campaign - map editor"
DESCRIPTION_wesnoth-font-freesans = "Battle for Wesnoth - font for greek translation"
DESCRIPTION_wesnoth-font-bepa = "Battle for Wesnoth - font for Eastern-Europe translations"
DESCRIPTION_wesnoth-dev = "Battle for Wesnoth - tools for content authoring"

FILES_${PN} = "${bindir}/wesnoth"
FILES_wesnoth-data = "${pkgddir}/wesnoth-coredata.zip \
	${pkgddir}/wesnoth-mp.zip ${pkgddir}/wesnoth-tutorial.zip \
	${pkgddir}/fonts/Vera.ttf"
FILES_wesnoth-editor = "${bindir}/wesnoth_editor ${pkgddir}/wesnoth-editor.zip"
FILES_wesnoth-sound = "${pkgddir}/wesnoth-sound.zip"
FILES_wesnoth-music = "${pkgddir}/music/*"
FILES_${PN}-dev = "${bindir}/wmlxgettext ${pkgddir}/wesnoth-devel.zip"
FILES_wesnoth-font-freesans = "${pkgddir}/fonts/FreeSans.ttf"
FILES_wesnoth-font-bepa = "${pkgddir}/fonts/Bepa-Roman.ttf"

RDEPENDS_${PN} = "wesnoth-data"
#RRECOMMENDS_${PN} = "wesnoth-sound, wesnoth-campaign-trow | virtual/wesnoth-campaign"
RRECOMMENDS_${PN} = "wesnoth-sound virtual/wesnoth-campaign"
RSUGGESTS_${PN} = "wesnoth-music"

RDEPENDS_wesnoth-editor = "wesnoth-data"


RDEPENDS_${PN}-locale-el-gr += "wesnoth-font-freesans"
RDEPENDS_${PN}-locale-cs += "wesnoth-font-bepa"
RDEPENDS_${PN}-locale-hu += "wesnoth-font-bepa"
RDEPENDS_${PN}-locale-pl += "wesnoth-font-bepa"
RDEPENDS_${PN}-locale-ru += "wesnoth-font-bepa"
RDEPENDS_${PN}-locale-sk += "wesnoth-font-bepa"

python () {
	pkgddir = bb.data.getVar("pkgddir", d, 1)
	for campaign in [ 'httt', 'ei', 'sotbe', 'tdh', 'trow' ]:
		bb.data.setVar("FILES_wesnoth-campaign-"+campaign, pkgddir+"/wesnoth-"+campaign+".zip", d)
		bb.data.setVar("RPROVIDES_wesnoth-campaign-"+campaign, "virtual/wesnoth-campaign", d)
		bb.data.setVar("RDEPENDS_wesnoth-campaign-"+campaign, "wesnoth", d)
}